Serial Communication: MIDI, and Max/MSP

Serial communications are supported between the Arduino board and a computer or other devices. The communication can be conducted via the USB connection and on digital pins 0 (RX) and 1 (TX). Thus, you cannot connect sensors to pins 0 and 1 if also using the serial functionality.

MIDI Output from the Arduino

A schematic of a MIDI (IN and OUT) interface (from http://www.borg.com/~jglatt/).

• From the schematic above, we need to connect a 220 ohm resistor between +5V and pin 4 of the MIDI connector and another 220 ohm resistor between pin 5 of the MIDI connector and the transmit pin (1) of the Arduino board.

• MIDI is a "serial" transmission standard.

• With the Arduino, we make use of the same serial functionality mentioned above:

  #define MIDI_ON 144
  #define MIDI_OFF 128
  #define MIDI_CHANNEL 0
  
  char status = 0;
  
  void setup()
  {
    Serial.begin( 31250 );       // set the MIDI baud rate
  }
  
  void loop()
  {
    status = MIDI_ON + MIDI_CHANNEL;
    midiSend( status, 60, 64 );   // send a MIDI ``note on'' message
  
    delay( 500 );                 // delay 500 milliseconds
  
    status = MIDI_OFF + MIDI_CHANNEL;
    midiSend( status, 60, 64 );   // send a MIDI ``note off'' message
  
    delay( 500 );                 // delay 500 milliseconds
  }
  
  // Send a MIDI message (without checking values)
  void midiSend( char cmd, char data1, char data2 )
  {
    Serial.print( cmd, BYTE );
    Serial.print( data1, BYTE );
    Serial.print( data2, BYTE );
  }
  

• In another example with MIDI, we can control the pitch of the MIDI message using a sensor.

• Note that we need to perform our internal scaling with a float variable to avoid exceeding the limits of the int data type.

  #define MIDI_ON 144
  #define MIDI_OFF 128
  #define MIDI_CHANNEL 0
  
  int fsrPin = 1;           // FSR pin
  char status = 0;
  int fsr = 0;
  float temp = 0.0;
  
  void setup()
  {
    Serial.begin( 31250 );  // set the MIDI baud rate
  }
  
  void loop()
  {
    fsr = analogRead( fsrPin );    // read the input pin
    temp = fsr;
    temp *= 40;
    temp /= 1024;
    temp += 50;                     // scale the value between 50 - 90
    fsr = temp;
  
    status = MIDI_ON + MIDI_CHANNEL;
    midiSend( status, fsr, 64 );   // send a MIDI ``note on'' message
  
    delay(500);                    // delay 500 milliseconds
  
    status = MIDI_OFF + MIDI_CHANNEL;
    midiSend( status, fsr, 64 );   // send a MIDI ``note off'' message
  
    delay(500);                    // delay 500 milliseconds
  }
  
  // Send a MIDI message (without checking values)
  void midiSend( char cmd, char data1, char data2 )
  {
    Serial.print( cmd, BYTE );
    Serial.print( data1, BYTE );
    Serial.print( data2, BYTE );
  }
  

• We can also use the Arduino for sequencing:

  #define MIDI_ON 144
  #define MIDI_OFF 128
  #define MIDI_CHANNEL 0
  #define MIDI_PROGRAM 192
  
  #define DRUM_CHANNEL 9
  #define BASS_CHANNEL 0
  
  #define KICK  35    // kick drum note number
  #define HAT 42      // closed hi-hat note number
  #define BASS 39     // bass program number
  
  char status = 0;
  int counter = 0;
  char bassNote = 28;
  char drumNote = 0;
  
  void setup()
  {
    Serial.begin( 31250 );  // set the MIDI baud rate
    Serial.print( MIDI_PROGRAM + BASS_CHANNEL, BYTE );  // Do MIDI program change for bass voice
    Serial.print( BASS, BYTE );
  }
  
  void loop()
  {
    if ( counter == 0 ) {
      drumNote = KICK;
      midiSend( MIDI_ON + DRUM_CHANNEL, drumNote, 64 );
      midiSend( MIDI_OFF + BASS_CHANNEL, bassNote, 64 );
      bassNote = 28;
      midiSend( MIDI_ON + BASS_CHANNEL, bassNote, 64 );
    }
    else if ( counter == 2 ) {
      drumNote = HAT;
      midiSend( MIDI_ON + DRUM_CHANNEL, drumNote, 64 );
    }
    else if ( counter == 4 ) {
      drumNote = KICK;
      midiSend( MIDI_ON + DRUM_CHANNEL, drumNote, 64 );
    }
    else if ( counter == 6 ) {
      drumNote = HAT;
      midiSend( MIDI_ON + DRUM_CHANNEL, drumNote, 64 );
    }
    else if ( counter == 8 ) {
      drumNote = KICK;
      midiSend( MIDI_ON + DRUM_CHANNEL, drumNote, 64 );
    }
    else if ( counter == 10 ) {
      drumNote = HAT;
      midiSend( MIDI_ON + DRUM_CHANNEL, drumNote, 64 );
    }
    else if ( counter == 12 ) {
      drumNote = KICK;
      midiSend( MIDI_ON + DRUM_CHANNEL, drumNote, 64 );
    }
    else if ( counter == 14 ) {
      drumNote = HAT;
      midiSend( MIDI_ON + DRUM_CHANNEL, drumNote, 64 );
    }
  
    counter++;
    if ( counter > 15 ) counter = 0;
  
    delay( 100 );                    // delay 100 milliseconds
  }
  
  // Send a MIDI message (without checking values)
  void midiSend( char cmd, char data1, char data2 )
  {
    Serial.print( cmd, BYTE );
    Serial.print( data1, BYTE );
    Serial.print( data2, BYTE );
  }
  

Interfacing the Arduino to Max/MSP

• A number of options for communicating between an Arduino and Max/MSP are provided in the Arduino playground: Max/MSP

• In general, this is accomplished using the Serial functionality in the Arduino and the serial object in Max.

• The following Max patch and Arduino code can be used to read the values from a single analog pin into Max:

  int fsrPin = 1;
  
  void setup() 
  { 
    Serial.begin( 9600 ); 
  }
   
  void loop() 
  {
  
    Serial.println( analogRead( fsrPin ) );
  
    delay( 100 );
  }
  

  

• For multiple inputs, as well as writing values from Max to the Arduino, the following Max patch and Arduino code provide a starting point:

  void setup() 
  { 
    Serial.begin( 115200 ); 
  }
   
  void loop() 
  {
    if ( Serial.available() ) {
      if ( Serial.read() != 'r' )  // If this isn't an 'r', we're reading from the wrong device
        return;
    }
  
    // Read from two analog pins and put a space between values.
    for ( int i=2; i<4; i++) {
      Serial.print( analogRead(i) );
      Serial.print(' ');
    }
    Serial.println();
  
    delay( 100 );  // Delay a bit.
  }
  

  

MIDI from the Arduino to Max

• We can also send MIDI messsages from the Arduino to Max/MSP by slightly modifying the approaches above. From the Arduino, we can send MIDI byte values as space-separated integers. In Max, the messages received by the serial object can be sent directly to the midiout object after conversion to a list of numbers.

• If you need to manipulate the message values, then you can unpack them as shown in the previous example.

  #define MIDI_ON 144
  #define MIDI_OFF 128
  #define MIDI_CHANNEL 0
  
  int status = 0;
  
  void setup()
  {
    Serial.begin( 115200 );       // set the baud rate
  }
  
  void loop()
  {
    status = MIDI_ON + MIDI_CHANNEL;
    midiSend( status, 60, 64 );   // send a MIDI ``note on'' message
  
    delay( 500 );                 // delay 500 milliseconds
  
    status = MIDI_OFF + MIDI_CHANNEL;
    midiSend( status, 60, 64 );   // send a MIDI ``note off'' message
  
    delay( 500 );                 // delay 500 milliseconds
  }
  
  // Send a MIDI message (without checking values)
  void midiSend( int cmd, int data1, int data2 )
  {
    Serial.print( cmd );
    Serial.print(' ');
    Serial.print( data1 );
    Serial.print(' ');
    Serial.print( data2 );
    Serial.println();
  }